Menyimpan Posisi Form

Jalankan aplikasi Ms. Visual Basic 6.0, silakan Anda pilih pola apa saja. Anda pindahkan posisi IDE Ms. Visual Basic 6.0 Anda (caranya: pastikan IDE Ms. Visual Basic 6.0 dalam keadaan mode WindowState: Normal/tidak Maximized, kemudian seret IDE Ms. Visual Basic 6.0 tersebut) ke sudut kanan bawah. Kemudian tutup kembali aplikasi Ms. Visual Basic 6.0 Anda.

Jalankan kembali aplikasi Ms. Visual Basic 6.0. Posisi IDE Ms. Visual Basic 6.0 Anda berada di pojok kanan bawah (pada posisi terakhir Anda menutup aplikasi Ms. Visual Basic 6.0 ini), bukan?
Nah, teknik berikut ini akan menjelaskan kepada Anda, bagaimana proses kerja dari kejadian di atas.

Buatlah project baru menggunakan pola StandardExe. Tambahkan module, ketik kode di bawah ini pada module:


Declare Function _
GetPrivateProfileString _
Lib "kernel32" _
Alias "GetPrivateProfileStringA" ( _
ByVal lpApplicationName As String, _
ByVal lpKeyName As Any, _
ByVal lpDefault As String, _
ByVal lpReturnedString As String, _
ByVal nSize As Long, _
ByVal lpFileName As String) As Long

Declare Function _
WritePrivateProfileString _
Lib "kernel32" _
Alias "WritePrivateProfileStringA" ( _
ByVal lpApplicationName _
As String, ByVal lpKeyName As Any, _
ByVal lpString As Any, _
ByVal lpFileName As String) As Long

'Prosedur untuk menuliskan setting ke sebuah file
Private Sub TulisSetting(myAPP$, sKunci As String, _
ByVal sNilai$)
    WritePrivateProfileString myAPP$, _
    sKunci, sNilai, App.Path & "\" & _
    App.Title & ".ini"
End Sub

'Fungsi untuk mengambil nilai setting dari sebuah file
Private Function AmbilSetting(myAPP$, sKunci As String, _
sDefault As String) As String
    Dim sTemp As String * 50
    Dim sNilai&

    sNilai& = GetPrivateProfileString( _
    myAPP$, sKunci, sDefault, sTemp, Len(sTemp), _
    App.Path & "\" & App.Title & ".ini")

    AmbilSetting = Left(sTemp, sNilai&)
End Function

'Prosedur untuk mengambil nilai posisi dan ukuran form
Sub AmbilPosisidanUkuran(frm As Form)
    frm.Left = CSng(AmbilSetting("Posisi", "Kiri", frm.Left))
    frm.Top = CSng(AmbilSetting("Posisi", "Atas", frm.Top))
    frm.Width = CSng(AmbilSetting("Ukuran", "Lebar", frm.Width))
    frm.Height = CSng(AmbilSetting("Ukuran", "Tinggi", frm.Height))
End Sub

'Prosedur untuk menyimpan nilai posisi dan ukuran form
Sub SimpanPosisidanUkuran(frm As Form)
    TulisSetting "Posisi", "Kiri", CStr(frm.Left)
    TulisSetting "Posisi", "Atas", CStr(frm.Top)
    TulisSetting "Ukuran", "Lebar", CStr(frm.Width)
    TulisSetting "Ukuran", "Tinggi", CStr(frm.Height)
End Sub

Ketik kode ini di form:

Private Sub Form_Load()
    AmbilPosisidanUkuran Me
End Sub

Private Sub Form_Unload(Cancel As Integer)
    SimpanPosisidanUkuran Me
End Sub


Sebelum menjalankan program, ubah properti StartUpPosition kepunyaan Form1 menjadi 0-Manual, kemudian lakukan penyimpanan. Sekarang jalankan program! Pindahkan posisi form, bila perlu ubah ukurannya. Tutup form dengan mengklik tombol close (x)!
Jalankan kembali program! Pastikan posisi dan ukuran form mengikuti posisi dan ukuran yang sebelumnya telah Anda ubah.

Dengan Windows Explorer, periksa alamat tempat penyimpanan project Anda ini. Di dalam folder tersebut akan terdapat sebuah file Configuration Setting (*.ini). Buka file tersebut! Akan tertulis kunci-kunci dan nilai yang merupakan media penyimpanan dari posisi dan ukuran form, seperti contoh di bawah ini:


[Posisi]
Kiri=7025
Atas=6435

[Ukuran]
Lebar=8295
Tinggi=4575


Ambil contoh kodenya di:
http://www.4shared.com/file/71707616/896f601f/Menyimpan_posisi_form.html

Perihal Novian Agung
Pengangguran

One Response to Menyimpan Posisi Form

  1. dedi mengatakan:

    salam hangat Mas. Artikelnya sangat membantu saya yg baru belajar VB6. ada yang saya mau tanyakan mas.
    Saya msh bingung cara menghubungkan 3 form dlm VB6. contoh :
    Saya tlh membuat 2 buah form yaitu :
    1. Form stok barang(nama barang, barang masuk, barang keluar)
    2. Form penjualan (Nama barang, harga, jumlah)
    lalu saya mau membuat form ketiga yaitu form laporan yang didalamnya mencakup
    -Stock akhir (hasil dr form stok barang)
    -laporan penjualan (hasil dari form penjualan)
    sekian pertanyaan dr saya, Sebelumnya saya ucapkan terima kasih

Tinggalkan Balasan

Isikan data di bawah atau klik salah satu ikon untuk log in:

Logo WordPress.com

You are commenting using your WordPress.com account. Logout / Ubah )

Gambar Twitter

You are commenting using your Twitter account. Logout / Ubah )

Foto Facebook

You are commenting using your Facebook account. Logout / Ubah )

Foto Google+

You are commenting using your Google+ account. Logout / Ubah )

Connecting to %s

%d blogger menyukai ini: